¿Existe una función estándar de Delphi para escapar de HTML?

Tengo un informe que se supone que debe tomar un control de cuadrícula y producir una salida HTML. Una de las columnas de la cuadrícula puede mostrar cualquiera de una serie de valores, o <Any>. Cuando esto se envía a HTML, por supuesto, termina en blanco.

Probablemente podría escribir alguna rutina para usar StringReplace para convertir eso en <Any> entonces mostraría este caso en particular correctamente, pero imagino que probablemente haya uno en el RTL en algún lugar que ya haya sido probado y lo haga bien. ¿Alguien sabe dónde podría encontrarlo?

Estoy 99 % seguro de que tal función no existe en RTL (a partir de Delphi 2009). Por supuesto, sin embargo, es trivial escribir tal función.

Actualizar

HTTPUtil.HTMLEscape es lo que estás buscando:

function HTMLEscape(const Str: string): string;

No me atrevo a publicar el código aquí (probablemente una violación de los derechos de autor), pero la rutina es muy simple. Codifica ““, “&” y “”” para <, >, &y ". También reemplaza los caracteres #92, #160..#255 a códigos decimales, por ejemplo \.

Este último paso no es necesario si el archivo es UTF-8, y también es ilógico, porque los caracteres especiales superiores, como ∮, se dejan como están, mientras que los caracteres especiales inferiores, como ×, están codificados.

Actualización 2

En respuesta a la respuesta de Stijn Sanders, realicé una prueba de rendimiento simple.

program Project1;

{$APPTYPE CONSOLE}

uses
  Windows, SysUtils;

var
  t1, t2, t3, t4: Int64;
  i: Integer;
  str: string;
const
  N = 100000;


function HTMLEncode(const Data: string): string;
var
  i: Integer;
begin

  result := '';
  for i := 1 to length(Data) do
    case Data[i] of
      '<': result := result + '&lt;';
      '>': result := result + '&gt;';
      '&': result := result + '&amp;';
      '"': result := result + '&quot;';
    else
      result := result + Data[i];
    end;

end;

function HTMLEncode2(Data: string):string;
begin
  Result:=
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
      Data,
      '&','&amp;',[rfReplaceAll]),
      '<','&lt;',[rfReplaceAll]),
      '>','&gt;',[rfReplaceAll]),
      '"','&quot;',[rfReplaceAll]);
end;

begin

  QueryPerformanceCounter(t1);
  for i := 0 to N - 1 do
    str := HTMLEncode('Testing. Is 3*4<3+4? Do you like "A & B"');
  QueryPerformanceCounter(t2);

  QueryPerformanceCounter(t3);
  for i := 0 to N - 1 do
    str := HTMLEncode2('Testing. Is 3*4<3+4? Do you like "A & B"');
  QueryPerformanceCounter(t4);

  Writeln(IntToStr(t2-t1));
  Writeln(IntToStr(t4-t3));

  Readln;


end.

la salida es

532031
801969

Parece que aquí hay un pequeño concurso 🙂 Aquí hay una implementación más:

function HTMLEncode3(const Data: string): string;
var
  iPos, i: Integer;

  procedure Encode(const AStr: String);
  begin
    Move(AStr[1], result[iPos], Length(AStr) * SizeOf(Char));
    Inc(iPos, Length(AStr));
  end;

begin
  SetLength(result, Length(Data) * 6);
  iPos := 1;
  for i := 1 to length(Data) do
    case Data[i] of
      '<': Encode('&lt;');
      '>': Encode('&gt;');
      '&': Encode('&amp;');
      '"': Encode('&quot;');
    else
      result[iPos] := Data[i];
      Inc(iPos);
    end;
  SetLength(result, iPos - 1);
end;

Actualización 1: se actualizó el código incorrecto proporcionado inicialmente.

Actualización 2: Y los tiempos:

HTMLEncode :   2286508597
HTMLEncode2:   3577001647
HTMLEncode3:    361039770

Usualmente solo uso este código:

function HTMLEncode(Data:string):string;
begin
  Result:=
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
      Data,
      '&','&',[rfReplaceAll]),
      '<','&lt;',[rfReplaceAll]),
      '>','&gt;',[rfReplaceAll]),
      '"','&quot;',[rfReplaceAll]),
      #13#10,'<br />'#13#10,[rfReplaceAll]);
end;

(¿derechos de autor? es fuente abierta)

Unit HTTPApp tiene una función llamada HTMLEncode. También tiene otras funciones relacionadas con HTML/HTTP.

No sé en qué versión de Delphi se introdujo, pero está el System.NetEncoding unidad que tiene:

TNetEncoding.HTML.Encode
TNetEncoding.HTML.Decode

funciones Leer aquí. Ya no necesitas bibliotecas externas para eso.

Desde la unidad Soap.HTTPUtil o simplemente HTTPUtil para versiones anteriores de Delphi, puede usar

function HTMLEscape(const Str: string): string;
var
  i: Integer;
begin
  Result := '';
  for i := Low(Str) to High(Str) do
  begin
    case Str[i]  of
    '<' : Result := Result + '&lt;';    { Do not localize }
    '>' : Result := Result + '&gt;';    { Do not localize }
    '&' : Result := Result + '&amp;';   { Do not localize }
    '"' : Result := Result + '&quot;';  { Do not localize }
{$IFNDEF UNICODE}
    #92, Char(160) .. #255 : Result := Result + '&#' + IntToStr(Ord(Str[ i ])) +';';  { Do not localize }
{$ELSE}
    // NOTE: Not very efficient
    #$0080..#$FFFF : Result := Result + '&#' + IntToStr(Ord(Str[ i ])) +';'; { Do not localize }
{$ENDIF}
    else
      Result := Result + Str[i];
    end;
  end;
end;

qué tal esa forma de reemplazar caracteres especiales:

    function HtmlWeg(sS: String): String;
var
  ix,cc: Integer;
  sC, sR: String;
begin
  result := sS;
  ix := pos('\u00',sS);

  while ix >0 do
  begin
    sc := copy(sS,ix+4,2) ;
    cc := StrtoIntdef('$' +sC,32);
    sR := '' + chr(cc);
    sS := Stringreplace(sS, '\u00'+sC,sR,[rfreplaceall]) ;
    ix := pos('\u00',sS);
  end;
  result := sS;
end;