Múltiples directorios bajo CMake

4 minutos de lectura

Multiples directorios bajo CMake
Aaron Yodaiken

Actualmente estoy usando make y autotools recursivos y estoy buscando migrar a CMake para un proyecto que se parece a esto:

lx/ (project root)
    src/
        lx.c (contains main method)
        conf.c
        util/
            str.c
            str.h
            etc.c
            etc.h
        server/
            server.c
            server.h
            request.c
            request.h
        js/
            js.c
            js.h
            interp.c
            interp.h
    bin/
        lx (executable)

¿Cómo debo hacer esto?

Multiples directorios bajo CMake
DLRdave

Si nunca hay una fuente más alta que el directorio lx/src, entonces no hay necesidad de la lx/CMakeLists.txt expediente. Si lo hay, debería ser algo como esto:

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx)

add_subdirectory(src)
add_subdirectory(dir1)
add_subdirectory(dir2)

# And possibly other commands dealing with things
# directly in the "lx" directory

… donde los subdirectorios se agregan en orden de dependencia de la biblioteca. Las bibliotecas que no dependen de nada más deben agregarse primero, y luego las bibliotecas que dependen de ellas, y así sucesivamente.

lx/src/CMakeLists.txt

cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
project(lx_exe)

add_subdirectory(util)
add_subdirectory(js)
add_subdirectory(server)

set(lx_source_files conf.c lx.c)
add_executable(lx ${lx_source_files})

target_link_libraries(lx server)
  # also transitively gets the "js" and "util" dependencies

lx/src/util/CMakeLists.txt

set(util_source_files
  etc.c
  etc.h
  str.c
  str.h
)
add_library(util ${util_source_files})

lx/src/js/CMakeLists.txt

set(js_source_files
  interp.c
  interp.h
  js.c
  js.h
)
add_library(js ${js_source_files})

target_link_libraries(js util)

lx/src/servidor/CMakeLists.txt

set(server_source_files
  request.c
  request.h
  server.c
  server.h
)
add_library(server ${server_source_files})

target_link_libraries(server js)
  # also transitively gets the "util" dependency

Luego, en un símbolo del sistema:

mkdir lx/bin
cd lx/bin

cmake ..
  # or "cmake ../src" if the top level
  # CMakeLists.txt is in lx/src

make

De forma predeterminada, el ejecutable lx terminará en el directorio “lx/bin/src” con este diseño exacto. Puede controlar en qué directorio termina usando la propiedad de destino RUNTIME_OUTPUT_DIRECTORY y el comando set_property.

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#prop_tgt:RUNTIME_OUTPUT_DIRECTORY

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:set_property

Consulte las bibliotecas de target_link_libraries ya sea por el nombre de destino de CMake, si la biblioteca se crea como un destino de CMake a través de add_library, o por la ruta completa al archivo de la biblioteca de lo contrario.

Consulte también el resultado de “cmake –help-command target_link_libraries”, o cualquier otro comando de cmake, y la documentación completa en línea para los comandos de cmake que se encuentra aquí:

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#section_Commands

http://www.cmake.org/cmake/help/cmake-2-8-docs.html#command:target_link_libraries

  • Muchas gracias, pero ¿cómo funciona el “transitivo” que obtiene las dependencias “js” y “util”?

    – Aarón Yodaiken

    15 de junio de 2011 a las 16:58

  • Esa es una característica de CMake: rastrea los comandos target_link_libraries a través de todo el árbol para construir el gráfico de dependencia en estructuras de datos internas y lo usa para generar líneas de comando de enlace correctas.

    – DLRdave

    16 de junio de 2011 a las 10:43

  • Como soy demasiado flojo para listar archivos, encontré que FILE(GLOB_RECURSE sourceVar ./ ​​*.cpp *.c *.h) es muy útil. También puede usar GLOB, que no recurre a subcarpetas. De lo contrario, gracias a DLRdave por ayudarme a comenzar con CMake también.

    – Budric

    4 de noviembre de 2011 a las 15:39

La biblioteca Steinberg VST3 tiene un método reutilizable que recorre recursivamente los subdirectorios y los agrega si incluyen un archivo CMakeLists.txt:

# add every sub directory of the current source dir if it contains a CMakeLists.txt
function(smtg_add_subdirectories)
    file(GLOB subDirectories RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} *)
    foreach(dir ${subDirectories})
        if(IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/${dir}")
            if(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${dir}/CMakeLists.txt")
                add_subdirectory(${dir})
            endif()
        endif()
    endforeach(dir)
endfunction()

https://github.com/steinbergmedia/vst3_cmake/blob/master/modules/SMTG_AddSubDirectories.cmake

¿Ha sido útil esta solución?

Esta web utiliza cookies propias y de terceros para su correcto funcionamiento y para fines analíticos y para mostrarte publicidad relacionada con sus preferencias en base a un perfil elaborado a partir de tus hábitos de navegación. Al hacer clic en el botón Aceptar, acepta el uso de estas tecnologías y el procesamiento de tus datos para estos propósitos. Configurar y más información
Privacidad